LAGBAR EN MDX, TRÈS TRÈS BELLE!

Commentaire de KOLANTA le 28/07/2003 16:56:17

Euh j'ai oublié de changer le niveau, je mettrai ça dans du 2, pas vous?

Commentaire de doodah le 28/07/2003 19:55:13

j'ai pas compris comment mettre la barre :( tu peus m'expliquer en detail :(

Commentaire de doodah le 28/07/2003 21:23:11

lol mais je les telecharges ou ses fichiers?

Commentaire de Cl1cKHer3 le 29/07/2003 10:25:18

niveau 2 :/

Commentaire de HeXoR le 29/07/2003 15:01:34

J'ai légèrement retouché ton code pour que la couleur de la LagBar se fonce (jaune -> rouge) en fonction du lag. Donc faut remplacer tout ce qu'il y a entre le "ON *:CTCPREPLY:LC &: {" et le "}", par :

ON *:CTCPREPLY:LC &: {
  set %lag $calc(($ticks -$2) / 1000),-3) s
  did -a lag 2 %lag
  did -a lag 3 $calc($remove(%lag, s) * 20)
  did -i lag 3 1 barcolor $rgb(255,$round($calc((100 - $remove(%lag, s) * 20) / 100 * 255), 0), 0),0)
  halt
}

Commentaire de HeXoR le 29/07/2003 15:11:53

Oué et puis en même temps ça raccourci ton code : moi en 1 ligne je fais cke ta mis en 10 lignes et en plus précis :p

Commentaire de PuMaZ le 06/08/2003 17:30:16

Pas mal mais même si c inutil t'aurai du fere un truc qui actualise quand le dialog est ouvert , dans l'event init »
.timerlag 0 5 actu

et un alias » alias actu { $iif($dialog(lag).title != $null,lm) }
enfin un truc tout con koi , sinon pas mal en effet

Commentaire de KOLANTA le 06/08/2003 22:33:12

Euh négatif, j'ai pas trop compris ce que tu voulais faire exactement :p

Commentaire de KOLANTA le 26/08/2003 12:13:27

Eh, suffit de chercher un peu sur Google, voici le lien: http://fiz.blackedout.org/dl/mdx.zip

Voilà mon garçon

Commentaire de Remi3d le 27/08/2003 11:43:08

putain je suis con ou quoi c bon laisse tombvé mon commentaire g compris..

Commentaire de KOLANTA le 02/09/2003 12:31:18

Tout d'abord Remi3d j'ai mes raisons de ne pas répondre, j'étais en Angleterre durant 4 jours, je ne peux pas être au four et au moulin en même temps donc tu pourras garder tes réflexions la prochaine fois... Alors si vous avez suivi toutes les instructions, c'est normal que la barre ne se lance pas aussitôt, elle se lance à la connexion et se ferme à la déconnexion. Voilà, ciao

Commentaire de Merakline le 03/09/2003 13:16:40

he bé jla voi pa kan mm jpense ke mon script il a des protection :) spa grave :)

Commentaire de VestaX le 22/12/2003 22:35:53

Hmm moi personnelement la barre ne change pas. ca reste bloqué a 7.22 et la barre n'augmente pas apparament elle beug ta barre

Commentaire de duduchmann le 03/08/2004 02:25:43

il y a moy d'avoir une news url pr dl les fichiers : mdx

Commentaire de duduchmann le 03/08/2004 04:36:38

j'été trouver un addon vennant d'ici aussi qui à lair de resemlé a celui que vous avez , mais en englais

; technique lag bar v.09 June 6 2002 for mIRC 5.91, 6.0, 6.01 and above by ex|l- (Ryan)
; Contact Email: linxsrc@berlin.com Website: http://techniquescript.cjb.net or http://kickme.to/technique
; For my friends and those who want a sweet pic win lagbar with options!
; Thanks to dohcan for tbwin.dll and sample script from which I learned from. :)
; Important note if you ignore notices or ctcps this wont work, depends on the method! <------------------ IMPORTANT
; The script will stop itself if it detects notice or ctcp ignores on yourself! Change your ignore status
; then type /lag.start to turn back on! Ignores on other users wont affect this, just yourself!
; Use the raw method if you have probs with the ignores!
; If you right click on lagbar it has popup and if you close lagbar to turn it back on type /lag.start
; Leave all this code in the same file and make sure tbwin.dll is in script dir or mirc dir!
; This is a bug fix version with oval switch added as well.
on master:TEXT:`lag:*:{ lag.msg }
menu @lag.win {
    &color
    .&lag
    ..&red:{ lag.red }
    ..&blue:{ lag.blue }
    ..&green:{ lag.green }
    ..&yellow:{ lag.yellow }
    ..&orange:{ lag.orange }
    ..-
    ..&custom:{ lag.custom }
    .-
    .&text:{ lag.stext }
    .&border:{ lag.sborder }
    .&background:{ lag.sface }
    .-
    .&default values:{ lag.defaults }
    .-
    &delay
    .&current $+($lag.delay,s):{ lag.stime }
    &style
    .$iif($readini($lag.spc($script),lagstuff,oval) == 1,$style(1) &oval,&oval):{ lag.oval.set $iif($readini($lag.spc($script),lagstuff,oval) == 1,0,1) | $lag.style }
    .-
    .$iif($readini($lag.spc($script),lagstuff,style) == small,$style(1) &small,&small):{ lag.style.set small | $lag.style }
    .$iif($readini($lag.spc($script),lagstuff,style) == classic,$style(1) &classic,&classic):{ lag.style.set classic | $lag.style }
    -
    $iif($active ischan,&say lag):{ lag.msg }
    &method
    .$iif($readini($lag.spc($script),lagstuff,method) == raw,$style(1) &raw,&raw):{ lag.method.raw }
    .$iif($readini($lag.spc($script),lagstuff,method) == ctcp,$style(1) &ctcp,&ctcp):{ lag.method.ctcp }
    .-
    .$iif($readini($lag.spc($script),lagstuff,method) == notice,$style(1) &notice,&notice):{ lag.method.notice }
    $iif($version >= 6.0,&network)
    .&current $lower($scid($timer(.lag.chk).cid).network):{ echo $color(info) -a *** Currently checking your lag on Network: $+($chr(2),$scid($timer(.lag.chk).cid).network,$chr(2)) Server: $+($chr(2),$scid($timer(.lag.chk).cid).server,$chr(2)) }
    -
    &close:{ lag.stop | echo $color(info) -a *** Stopped all lag bar functions, to turn back on type /lag.start }
}
alias -l lag.bar {
    lag.win.size
    tbwin Attach @lag.win
    var %z = $dll($_tbwin,GetTBInfo,NOT_USED),%w = $gettok(%z,1,32),%h = $gettok(%z,2,32)
    lagbar.size %w %h
    tbwin OnSize /lagbar.size
    lag.update
    window -a @lag.win
}
alias lag.update { if ($window(@lag.win)) { $lag.style } }
alias lag.win.size { window -phB +d @lag.win 0 0 200 22 }
alias lagbar.size { window @lag.win $calc($1 - 195) $int($calc(($2 - 22) / 2)) 200 22 }
alias -l lag.oval.set { writeini -n $lag.spc($script) lagstuff oval $1 }
alias -l lag.oval { return $iif($readini($lag.spc($script),lagstuff,oval) == 1,d)) }
alias -l lag.style.set { writeini $lag.spc($script) lagstuff style $1 }
alias -l lag.sface { writeini -n $lag.spc($script) lagstuff face $$input(Enter a rgb color/value for the background eg. $+($chr(36),rgb,$chr(40),face,$chr(41)),129) | $lag.style }
alias -l lag.style { return $iif($readini($lag.spc($script),lagstuff,style),$+(lag.,$ifmatch),$+(lag.,classic)) }
alias -l lag.face { return $iif($readini($lag.spc($script),lagstuff,face),$ifmatch,$rgb(face))) }
alias -l lag.stext {    writeini -n $lag.spc($script) lagstuff text $$input(Enter a rgb color/value for the text eg. $+($chr(36),rgb,$chr(40),text,$chr(41)),129) | $lag.style }
alias -l lag.text { return $iif($readini($lag.spc($script),lagstuff,text),$ifmatch,$rgb(text))) }
alias -l lag.sborder { writeini -n $lag.spc($script) lagstuff border $$input(Enter a rgb color/value for the border eg. $+($chr(36),rgb,$chr(40),text,$chr(41)),129) | $lag.style }
alias -l lag.border { return $iif($readini($lag.spc($script),lagstuff,border),$ifmatch,$rgb(text))) }
alias -l lag.defaults { remini $lag.spc($script) lagstuff face | remini $lag.spc($script) lagstuff text | remini $lag.spc($script) lagstuff border | remini $lag.spc($script) lagstuff color | $lag.style }
alias -l lag.classic {
    var %l = $hget(txlag,curlag),%t = Lag: $lag.isms($hget(txlag,curlag))
    drawrect -nrf @lag.win $lag.face 1 0 0 200 22
    drawtext -nro @lag.win $lag.text Tahoma -7 $calc(65 - $int($width(%t, Tahoma, -7))) 7 %t
    drawrect $+(-nr,$lag.oval) @lag.win $lag.border 2 83 3 105 18
    drawrect $+(-nrf,$lag.oval) @lag.win $lag.color 1 85 5 $iif(%l > 10,$iif(%l != ??,101,0),$int($calc(%l * 10.1))) 14
    drawdot @lag.win
}
alias -l lag.small {
    var %l = $hget(txlag,curlag),%t = Lag: $lag.isms($hget(txlag,curlag))
    drawrect -nrf @lag.win $lag.face 1 0 0 200 22
    drawtext -nr @lag.win $lag.text Tahoma -7 $int($calc((110 - $width(%t, Tahoma, -7)) / 2)) 7 %t
    drawrect $+(-nr,$lag.oval) @lag.win $lag.border 1 83 7 105 12
    drawrect $+(-nrf,$lag.oval) @lag.win $lag.color 1 85 9 $iif(%l > 10,$iif(%l != ??,101,0),$int($calc(%l * 10.1))) 8
    drawdot @lag.win
}
alias lag.deploy {
    if ($1) { writeini -n $lag.spc($script) lagstuff text $1 }
    if ($2) { writeini -n $lag.spc($script) lagstuff border $2 }
    if ($3) { writeini -n $lag.spc($script) lagstuff color $3 }
    if ($4) { writeini -n $lag.spc($script) lagstuff face $4 }
    lag.stop
    lag.start
}
alias lag.scheme { echo $color(info) -a *** technique lag bar scheme settings, pass this to a friend /lag.deploy $lag.text $lag.border $lag.color $lag.face }
on ^*:notice:lag*:?: {
    if ($nick == $me) && ($2 isnum) && ($hget(txlag)) {
    hadd txlag curlag $calc($calc($ticks - $2) / 1000)
    lag.update
    haltdef
    }
    elseif (!$hget(txlag)) {
    lag.stop
    echo $color(info) -a *** Hash table error shutting down lag bar!
    haltdef
    }
}
ctcp *:lag*:?:{
    if ($nick == $me) && ($2 isnum) && ($hget(txlag)) {
    hadd txlag curlag $calc($calc($ticks - $2) / 1000)
    lag.update  
    halt
    }
    elseif (!$hget(txlag)) {
    lag.stop
    echo $color(info) -a *** Hash table error shutting down lag bar!
    halt
    }
}
raw 421:*:{
    if ($1 == $me) && ($2 isnum) {
    if ($hget(txlag)) hadd txlag curlag $calc($calc($ticks - $2) / 1000)
    lag.update
    halt
    }
}
alias lag.start {
    if (!$readini($lag.spc($script),lagstuff,method)) { lag.method }
    if (!$hget(txlag)) {
    hmake txlag 1
    hadd txlag curlag ??
    }
    lag.bar
    lag.fill
    lag.chk
}
alias -l lag.method {
    $iif($input(Would you like to use a notice for lag check if not press no then a ctcp will be used you can also use the raw method from popup!,8,Lag method.),writeini -n $lag.spc($script) lagstuff method notice,writeini $lag.spc($script) lagstuff method ctcp)
    lag.stop
    $iif($server,lag.start)
}
alias -l _tbwin {
    if ($isfile($+($scriptdir,tbwin.dll))) {
    return $lag.spc($+($scriptdir,tbwin.dll))
    }
    elseif ($findfile($mircdir,tbwin.dll,1)) {
    return $lag.spc($ifmatch)
    }
    else {
    lag.stop
    .timer.lag.error $iif($version >= 6.0,-i) 2 5 echo $color(info) -a *** Couldn't locate tbwin.dll in your mIRC or script directory, please put tbwin.dll in your mIRC or script directory so lag bar can function!
    }
}
alias -l lag.color {
    if ($readini($lag.spc($script),lagstuff,color)) {
    return $ifmatch
    }
    else {
    return $rgb(255,0,0)
    }
}
alias -l lag.spc { return $+($chr(34),$1-,$chr(34)) }
alias -l lag.red { writeini -n $lag.spc($script) lagstuff color $rgb(255,0,0) | lag.fill }
alias -l lag.blue { writeini -n $lag.spc($script) lagstuff color $rgb(0,0,255) | lag.fill }
alias -l lag.green { writeini -n $lag.spc($script) lagstuff color $rgb(12,240,30) | lag.fill }
alias -l lag.yellow { writeini -n $lag.spc($script) lagstuff color $rgb(255,255,0) | lag.fill }
alias -l lag.orange { writeini -n $lag.spc($script) lagstuff color $rgb(252,127,0) | lag.fill }
alias -l lag.custom { writeini -n $lag.spc($script) lagstuff color $$input(Enter a custom rgb color/value which you can get by using $+($chr(36),rgb) identifier!,129) | lag.fill }
alias -l tbwin { dll $_tbwin $1- }
alias -l lag.chk {
    if ($readini($lag.spc($script),lagstuff,method) != raw) {
    .timer.lag.chk $iif($version >= 6.0,-i) 0 $lag.delay $&
        $+(lag.,$readini($lag.spc($script),lagstuff,method)) | lag.ignore.chk
    }
    else {
    .timer.lag.chk $iif($version >= 6.0,-i) 0 $lag.delay $+(lag.,$readini($lag.spc($script),lagstuff,method))
    }
}
alias -l lag.delay { return $iif($readini($lag.spc($script),lagstuff,delay),$ifmatch,20) }
alias lag.stime {
    writeini -n $lag.spc($script) lagstuff delay $$input(Delay in seconds to check lag recommended 10 or more seconds!,129)
    lag.chk
}
alias -l lag.method.raw { writeini -n $lag.spc($script) lagstuff method raw | lag.stop | $iif($server,lag.start) }
alias -l lag.method.ctcp { writeini -n $lag.spc($script) lagstuff method ctcp | lag.stop | $iif($server,lag.start) }
alias -l lag.method.notice { writeini -n $lag.spc($script) lagstuff method notice | lag.stop | $iif($server,lag.start) }
alias -l lag.ctcp { $iif($server,.ctcp $me lag $ticks) }
alias -l lag.notice { $iif($server,.notice $me lag $ticks) }
alias -l lag.raw { $iif($server,.raw $ticks) }
alias -l lag.isms { if ($1 isnum) { return $+($1,s) } | else { return $1 } }
alias -l lag.msg { $iif($active ischan,msg # Currently my lag is: $lag.isms($hget(txlag,curlag))) }
alias lag.stop {
    $iif($window(@lag.win),window -c @lag.win)
    .timer.lag.chk off
    $iif($hget(txlag),hfree txlag)
}
on *:load: {
    if ($version >= 5.91) {
    lag.style.set classic
    lag.oval.set 0
    lag.method
    echo $color(info) -a *** technique lag bar v.09 loaded successfully, right click on lagbar for options!
    }
    else {
    echo $color(info) -a *** This needs mIRC version 5.91+ this is $version , this addon wont work unloading it!
    .unload -rs " $+ $script $+ "
    }
}
on *:connect:{
    if ($version >= 6.0) && (!$window(@lag.win)) {
    lag.start
    }
    elseif ($version == 5.91) {
    lag.start
    }
}
on *:unload:{ lag.stop | remini $lag.spc($script) lagstuff }
on *:active:*:{ if ($version >= 6.0) && ($timer(.lag.chk)) && ($activecid != $timer(.lag.chk).cid) { scid $activecid lag.chk } }
on *:disconnect:{
    if ($version >= 6.0) {
    var %s = 1,%t
    while (%s <= $scon(0)) {
        if ($scon(%s).status == connected) { inc %t }
        inc %s
    }
    $iif(!%t,lag.stop)
    }
    elseif ($version == 5.91) {
    lag.stop
    }
}
alias -l lag.fill {
    if ($hget(txlag)) {
    var %f = 1,%g = 30,%h = $hget(txlag,curlag)
    while (%f <= 10) {
        $+(.timer.lag.fill,$r(1,999)) -h 1 %g hadd txlag curlag %f  
        $+(.timer.lag.fill2,$r(1,9999)) -h 1 $calc(%g + 1) lag.update
        inc %f
        inc %g 30
    }
    }
    if ($hget(txlag)) {
    var %i = 10,%j = 300
    while (%i >= 0) {
        $+(.timer.lag.clr,$r(1,999)) -h 1 %j hadd txlag curlag %i
        $+(.timer.lag.clr2,$r(1,9999)) -h 1 $calc(%j + 1) lag.update
        dec %i
        inc %j 30
    }
    }
    .timer.lag.restore -h 1 1000 hadd txlag curlag %h
    .timer.lag.restore2 -h 1 1050 lag.update
}
alias -l lag.ignore.chk {
    if ($ignore($address($me,5))) && (notice isin $ignore($ifmatch).type) && ($readini($lag.spc($script),lagstuff,method) == notice) {  
    .timer.lag.error2 1 5 echo $color(info) -a *** You are ignoring notice's from yourself lag bar wont work,fix then type /lag.start
    lag.stop
    }
    elseif ($ignore($address($me,5))) && (ctcp isin $ignore($ifmatch).type) && ($readini($lag.spc($script),lagstuff,method) == ctcp) {
    .timer.lag.error3 1 5 echo $color(info) -a *** You are ignoring ctcp's from yourself lag bar wont work, fix then type /lag.start
    lag.stop
    }
    elseif ($ignore(*!*@*)) && (notice isin $ignore($ifmatch).type) && ($readini($lag.spc($script),lagstuff,method) == notice) {
    .timer.lag.error4 1 5 echo $color(info) -a *** You are ignoring notice's, your lag bar wont work, fix then type /lag.start
    lag.stop
    }
    elseif ($ignore(*!*@*)) && (ctcp isin $ignore($ifmatch).type) && ($readini($lag.spc($script),lagstuff,method) == ctcp) {
    .timer.lag.error5 1 5 echo $color(info) -a *** You are ignoring ctcps, your lag bar wont work, fix then type /lag.start
    lag.stop
    }
}

; End of technique lag bar v.09 "Show some technique


Noublions pas Faire Yes Puis No en second

Commentaire de InFerNaLeX le 05/12/2004 03:57:01

rha bah avec un site en anglais je suis meme pas capable de trouvé les fichier mdx et dll donc je peux pas dl =(

Commentaire de VestaX le 23/08/2005 21:50:24

HeXoR, moi ca ne marche pas la couleur, c'est normal?