MP3 SIMPLE EN MOINS DE 100 LIGNES MEME SI C'EST DU DEJA VUE

menu menubar,channel {
  Mp3 by arc:amp3
}
alias amp3 { dialog -md mp3 mp3 }
dialog mp3 {
  title "Lecteur Mp3 (archeloga) 15.11.05"
  size -1 -1 167 86
  option dbu
  edit "", 1, 2 3 31 10, read autohs
  edit "", 2, 2 14 31 10, read autohs
  edit "", 3, 2 25 31 10, read autohs
  edit "", 4, 2 36 31 10, read autohs
  edit "", 5, 2 47 31 10, read autohs
  button "Rw", 6, 2 71 15 12
  button "Stop", 7, 20 71 15 12
  button "Break", 8, 38 71 15 12
  button "Play", 9, 56 71 15 12
  button "Fw", 10, 74 71 15 12
  list 11, 40 10 122 47, size vsbar
  button "+", 12, 92 58 15 12
  button "-", 13, 110 58 15 12
  button "+ R", 14, 128 58 15 12
  button "Del", 15, 146 58 15 12
  button "+ S", 17, 38 58 15 12
  button "Mute", 18, 56 58 15 12
  button "- S", 19, 74 58 15 12
  edit "", 20, 40 1 122 10, read autohs
  button "Quitter !", 21, 128 72 34 12
  edit "", 22, 2 58 31 10, read autohs
  button "?", 16, 92 71 15 12
}
on *:dialog:mp3:init:*:mp3la
on *:dialog:mp3:sclick:*:{
  if $did == 11 { did -ra mp3 20 $did(mp3,11).seltext }
  elseif $did == 6 {
    if (%mp3rf == 1) { set %mp3rf $lines(txt.txt) | splay $read(txt.txt,%mp3rf) | dialog -t mp3 $nopath($read(txt.txt,%mp3rf)) | mp3info }
    else { dec %mp3rf | splay $read(txt.txt,%mp3rf) | dialog -t mp3 $nopath($read(txt.txt,%mp3rf)) | mp3info }
  }
  elseif $did == 7 { splay stop }
  elseif $did == 9 { splay $read(txt.txt,$did(mp3,11).sel) | dialog -t mp3 $did(mp3,11).seltext | set %mp3rf $did(mp3,11).sel | mp3info }
  elseif $did == 10 {
    if (%mp3rf == $lines(txt.txt)) { splay $read(txt.txt,1) | set %mp3rf 1 | dialog -t mp3 $nopath($read(txt.txt,%mp3rf)) | mp3info }
    else { inc %mp3rf | splay $read(txt.txt,%mp3rf) | dialog -t mp3 $nopath($read(txt.txt,%mp3rf)) | mp3info }
  }
  elseif $did == 12 { write txt.txt $sfile(*.mp3,Recherche d'un fichier Mp3,Ajouter le mp3) | refreshmp3 }
  elseif $did == 14 {
    var %mp3a $sdir(dir,Dossier Mp3)
    var %mp3ax 1
    while (%mp3ax <= $findfile(%mp3a,*.mp3,0)) {
      write txt.txt $findfile(%mp3a,*.mp3,%mp3ax) | inc %mp3ax
    }
    mp3la
  }
  elseif $did == 15 { .remove txt.txt | did -r mp3 11 }
  elseif $did == 16 { echo -a - | echo -a Mp3 v1 par archeloga | echo -a Pour dire ce que tu écoute tape !play avec info tape !pinfo
  echo -a si tu as des problemes avec le Mp3 écrit moi sur warthog15@hotmail.com | echo -a - }
  elseif $did == 8 {
    if (%loly == 1) { splay resume | unset %loly }
    else { splay pause | set %loly 1 }
  }
  elseif $did == 18 { 
    if (%muet == 1) { vol -vu2 | unset %muet }
    else { vol -vu1 | set %muet 1 }
  }
  elseif $did == 17 { vol -w $calc($Int($Vol(Wave)) +5000) }
  elseif $did == 19 { vol -w $calc($Int($Vol(Wave)) - 5000) }
  elseif $did == 13 { 
    write -dl [ $+ [ $did(mp3,11).sel ] ] txt.txt 
    did -d $dname 11 $did(mp3,11).sel 
  }
  elseif $did == 21 { splay stop | dialog -x mp3 }
}
on *:dialog:mp3:dclick:*:{
  if $did == 11 { splay $read(txt.txt,$did(mp3,11).sel) | dialog -t mp3 $did(mp3,11).seltext | set %mp3rf $did(mp3,11).sel | mp3info }
}
alias -l mp3la {
  var %mp3aa 1
  while (%mp3aa <= $lines(txt.txt)) {
    did -a mp3 11 $nopath($read(txt.txt,%mp3aa)) | inc %mp3aa
  }
}
alias -l refreshmp3 { did -r mp3 11 | mp3la }
alias -l mp3info { 
  did -ra mp3 1 $sound($read(txt.txt,$did(mp3,11).sel)).artist
  did -ra mp3 2 $sound($read(txt.txt,$did(mp3,11).sel)).year
  did -ra mp3 3 $sound($read(txt.txt,$did(mp3,11).sel)).album
  did -ra mp3 4 $sound($read(txt.txt,$did(mp3,11).sel)).genre
  did -ra mp3 5 $duration($calc($sound($read(txt.txt,$did(mp3,11).sel)).length /1000).2)
  did -ra mp3 22 $round($calc($file($read(txt.txt,$did(mp3,11).sel))/1000000),2) Mb
}
on *:input:#:{
  if $1 == !play { .timermp32 1 1 describe $active écoute présentement $nopath($read(txt.txt,%mp3rf)) $+([,$duration($calc($insong.pos /1000)),/,$duration($calc($sound($read(txt.txt,%mp3rf)).length /1000)),]) $+([,$round($calc($insong.pos /1000 *100 / $calc($sound($read(txt.txt,%mp3rf)).length /1000)),1),%,]) }
  if $1 == !pinfo { .timermp32 1 1 describe $active écoute présentement $nopath($read(txt.txt,%mp3rf)) $+([,$duration($calc($insong.pos /1000)),/,$duration($calc($sound($read(txt.txt,%mp3rf)).length /1000)),]) $+([,$round($calc($insong.pos /1000 *100 / $calc($sound($read(txt.txt,%mp3rf)).length /1000)),1),%,]) $+([,$round($calc($file($read(txt.txt,%mp3rf))/1000000),2),Mb]) $+([,$sound($read(txt.txt,%mp3rf)).bitrate,Kbps]) $+([,Vol: $Int($Vol(Wave)),]) $+([Genre: ,$sound($read(txt.txt,$did(mp3,11).sel)).genre,]) }
}