SNIPPET $M2H : MIRC -> HTML

/*
Alias permettant de mettre du texte mirc au format HTML , de facon a conserver les couleurs sur une page de quotes par exemple :)
(m2h comme mirc to html)
le sens html -> mirc a déja été fait en partie par  ic3flamez , sachant que les couleurs sont limitées avec mirc on ne peut pas vraiment aller plus loin)
Utilisation : //Echo -a $m2h(string)
*/
Alias m2h {
  ;codes couleur > ascii : b > 2 , k > 3 , o > 15 , r > 22 , u > 31
  var %x $1-
  ;substitutions des gras
  var %y = $regsub(%x,/\002(.*?)(?:\002|$)/g,<b>\1</b>,%x)
  ;substitution des soulignés (\031 ne fonctionne pas dans la regex)
  var %y = $regsub(%x,/ $chr(31) (.*?)(?: $chr(31) |$)/gx,<u>\1</u>,%x) , %x = $remove(%x,<b></b>,<u></u>)
  ;permet que les ctrl + O éliminent le gras et le souligné , + Reverse
  var %y = $regsub(%x,/(<b>.*) $chr(15) (.*)</b>/gx,\1</b> $+ $chr(15) $+ \2</b>,%x) , %x = $replace(%x,$chr(15),$+($chr(3),01,$chr(44),00),$chr(22),$+($chr(3),00,$chr(44),01))
  ;substitution des ctrl + K
  while $regex(%x,^(.*)\003(\d{0,2},?\d{0,2})(.*?)(?:\003|$)(.*)) {
    tokenize 44 $regml(2)
    %x = $regml(1) $+ <span style="color: $+ $col($iif($1 isnum 0-15,$1,1)) $+ ;background-color: $+ $col($iif($2 isnum 0-15,$2,0)) $+ "> $+ $regml(3) $+ </span> $+ $regml(4) 
  }
  return $+(<font face="tahoma" size="2">,%x,<p>)
}
Alias -l col { tokenize 44 $rgb($color($1)) | return $+($chr(35),$base($1,10,16,2),$base($2,10,16,2),$base($3,10,16,2)) }
Alias m2htxt {
  var %i 1,%m $lines($$1)
  .fopen h1 $1
  .fopen -no h2 log.html
  while (%i <= %m) {
    .fwrite -n h2 $iif($fread(h1),$m2h($ifmatch),$chr(15))
    inc %i
  }
  .fclose h?
  run log.html
}