TOOLBAR GRAPHIQUE SANS DLL

alias -l w { writeini -n toolbar.ini para $1 $2 }
alias -l r1 { return $readini(toolbar.ini,n,item,n $+ $1) }
alias -l r2 { return $readini(toolbar.ini,para,$1) }
alias -l µ { if ( $did($1).text != $null) { return $ifmatch } | else { return 0 } }
alias -l g { return $gettok($r2($1),$2,44) }

alias csb { 
  drawline -r @& $+ $1 $rgb(155,155,155) $2 $3 $5 $calc($3 + $4) $5
  drawline -r @& $+ $1 $rgb(155,155,155) $2 $calc($3 + $4) $2 $calc($3 + $4) $5
  drawline -r @& $+ $1 $rgb(40,40,40) $2 $3 $2 $calc($3 + $4) $2
  drawline -r @& $+ $1 $rgb(40,40,40) $2 $3 $2 $3 $5
  .timertool -m 1 100 dcsb $1 $2 $3 $4 $5
}

alias dcsb { 
  drawline -r @& $+ $1 $rgb(155,155,155) $2 $3 $2 $calc($3 + $4) $2 
  drawline -r @& $+ $1 $rgb(155,155,155) $2 $3 $2 $3 $5
  drawline -r @& $+ $1 $rgb(40,40,40) $2 $3 $5 $calc($3 + $4) $5
  drawline -r @& $+ $1 $rgb(40,40,40) $2 $calc($3 + $4) $2 $calc($3 + $4) $5
}

alias bouton {
  drawrect -rf @& $+ $1 $rgb($2,$3,$3) $5 $6 $5 $7 $8
  drawline -r @& $+ $1 $rgb(155,155,155) $5 $6 $5 $calc($6 + $7) $5 
  drawline -r @& $+ $1 $rgb(155,155,155) $5 $6 $5 $6 $8
  drawline -r @& $+ $1 $rgb(40,40,40) $5 $6 $8 $calc($6 + $7) $8
  drawline -r @& $+ $1 $rgb(40,40,40) $5 $calc($6 + $7) $5 $calc($6 + $7) $8
}

alias color.tool { 
  window -hkp +b @aperçu 0 0 100 100
  drawfill -r @aperçu $rgb(0,0,0) $rgb(0,0,0) 0 0
  drawsave @aperçu @aperçu.bmp
  dialog -m toolbar toolbar
}

alias -l ouvrir { 
  set %itr 1 
  did -a Toolbar 7 $1
  while ( $readini($1,n,texte, n $+ %itr) != $null ) { did -a Toolbar 6 $readini($1,n,texte, n $+ %itr) $crlf | inc %itr }
  if ($exists($1)) {
    $w(file,$1)
    did -a toolbar 15 $readini($1,n,para,b1)
    did -a toolbar 16 $readini($1,n,para,b2)
    did -a toolbar 17 $readini($1,n,para,b2)
    did -a toolbar 23 $gettok($readini($1,n,para,selected),1,44)
    did -a toolbar 24 $gettok($readini($1,n,para,selected),2,44)
    did -a toolbar 25 $gettok($readini($1,n,para,selected),3,44)
    did -a toolbar 31 $gettok($readini($1,n,para,normal),1,44)
    did -a toolbar 32 $gettok($readini($1,n,para,normal),2,44)
    did -a toolbar 33 $gettok($readini($1,n,para,normal),3,44)
  }
  else { did -a toolbar 15,16,17,23,24,25,31,32,33 0 }
  did -a toolbar 5 $nopath($1)
}

alias genere.toolbar {
  set %itr 1 
  if ($exists($3)) { 
    .remini toolbar.ini item
    $w(file,$3)
    $w(normal,$readini($3,n,para,normal))
    $w(selected,$readini($3,n,para,selected))
    while ( $readini($3,n,texte,n $+ %itr) != $null ) {
      if ( %itr <= 3 ) { $w(b $+ %itr,$readini($3,n,para,b $+ %itr)) }
      writeini -n toolbar.ini item n $+ %itr $readini($3,n,texte,n $+ %itr)
      inc %itr
    }
  }
  else { echo -a le fichier $3 n'existe pas arret du processus | halt }
  set %itr 1
  $w(max,0)
  if ( $window(@& $+ $1)) { window -c @& $+ $1 }
  window -hkp +b @& $+ $1
  while ( $r1(%itr) != $null ) {
    if ( $r2(max) <= $len($gettok($r1(%itr),1,58)) ) { $w(max,$len($gettok($r1(%itr),1,58))) }
    inc %itr
  } 
  $w(get0,$calc(%itr -1))
  if ( $2 = pleine ) {
    set %position 3
    set %itr 1
    window -a @& $+ $1 0 0 $calc($window(-1).w -84) 25
    $w(type,$calc($int($calc($calc($window(-1).w -84) / $r2(get0))) -10))
    while ( %itr <= $r2(get0) ) { 
      $bouton($1,$r2(b1),$r2(b2),$r2(b3),2,%position,$r2(type),20)
      drawtext -r @& $+ $1 $rgb($g(normal,1),$g(normal,2),$g(normal,3)) $calc(%position +5) 2 $gettok($r1(%itr),1,58)
      inc %position $calc($r2(type) +10)
      inc %itr
    }
  }
  elseif ( $2 = classique ) { 
    set %itr 1
    set %position 3
    $w(type,$calc($r2(max) *10))
    while ( %itr <= $r2(get0) ) { 
      $bouton($1,$r2(b1),$r2(b2),$r2(b3),2,%position,$r2(type),20)
      drawtext -r @& $+ $1 $rgb($g(normal,1),$g(normal,2),$g(normal,3)) $calc(%position +5) 2 $gettok($r1(%itr),1,58)
      inc %position $calc($r2(type) +10)
      inc %itr
    }
    window -a @& $+ $1 0 0 $calc(%position +2) 25
  }
}

dialog toolbar { 
  title "Toolbar Config"
  size -1 -1 400 500

  Box "Texte a interpreté ",39, 10 140 370 291
  edit "", 6, 20 155 350 250, return, multi, vsbar
  button "Sauvegarder", 4,  20 435 100 20  , ok ,flat
  edit "", 7,140 435 110 20, multi,
  button "Ouvrir", 8, 20 407 100 20 ,flat
  button "Help ?" ,9, 250 407 110 20,flat
  text ,5, 250 435 200 20

  Box "Bouton" , 10,10 10 80 110
  text "rouge" ,12 , 20 30 30 15
  text "vert" , 13, 20 50 30 15
  text "bleu" ,14 , 20 70 30 15
  edit "" , 15, 50 30 30 20
  edit "" , 16, 50 50 30 20
  edit "" , 17,50 70 30 20
  button "aperçu",18,20 95 60 20,flat

  Box "Sélection" ,19 ,90 10 80 110
  text "rouge" ,20 ,100 30 30 15
  text "vert" , 21,100 50 30 15
  text "bleu" ,22 ,100 70 30 15
  edit "" ,23 , 130 30 30 20
  edit "" ,24 , 130 50 30 20
  edit "" ,25 , 130 70 30 20
  button "aperçu",26,100 95 60 20,flat

  Box "Normal" , 27,170 10 80 110
  text "rouge" ,28 ,180 30 30 15
  text "vert" , 29,180 50 30 15
  text "bleu" , 30,180 70 30 15
  edit "" ,31 , 210 30 30 20
  edit "" , 32, 210 50 30 20
  edit "" , 33,210 70 30 20
  button "aperçu",34,180 95 60 20,flat

  button "Aperçu General",35, 100 460 230 20,flat
  icon 37, 270 20 100 100, $mircdir $+ @aperçu.bmp,
  text "",38, 270 130 100 20
}

on *:dialog:toolbar:init:0: { $ouvrir($eval($r2(file),2)) }
on *:dialog:toolbar:sclick:4:{ 
  set %itr 1 
  unset %ligne
  if ( $did(7).text = toolbar.ini ) { 
    echo -s N'utilisez pas de fichier nommé "toolbar.ini" 
    echo -s Le fichier " $+ $ifmatch $+ " est renommée en " $+ $gettok($ifmatch,1,46) $+ (1) $+.ini $+ "
    $w(conflit,$gettok($ifmatch,1,46) $+ (1) $+.ini)
    did -a toolbar 7 $r2(conflit)
  }
  if ($exists($did(7).text)) { .remove $did(7).text }
  while ( %itr <= $did(6).lines) { 
    if ( $gettok($did(6,%itr).text,0,58) != 2 ) && ( $did(6,%itr).text != $null ) { set %ligne %ligne %itr }
    writeini -n $did(7).text texte n $+ %itr $did(6,%itr).text 
    inc %itr
  }
  $w(file,$did(7).text)
  writeini -n $r2(file) para normal $µ(31) $+ , $+ $µ(32) $+ , $+ $µ(33)
  writeini -n $r2(file) para selected $µ(23) $+ , $+ $µ(24) $+ , $+ $µ(25)
  writeini -n $r2(file) para b1 $µ(15)
  writeini -n $r2(file) para b2 $µ(16)
  writeini -n $r2(file) para b3 $µ(17)
  if ( %ligne != $null ) { dialog -m erreur.t erreur.t }
}

on *:dialog:toolbar:sclick:8:{ did -r toolbar 6 | $ouvrir($sfile($mircdir,Choisit un fichier texte,Ok)) }
on *:dialog:toolbar:sclick:9:{ run aide-toolbar.txt }

on *:dialog:toolbar:sclick:18:{
  set %itr 1 
  if ( $window(@&aperçue) != $null ) { window -c @&aperçue | .timeratool off }
  while ( %itr <= 5) { 
    writeini -n aperçu.ini texte n $+ %itr Bouton:echo -a aperçu des boutons 
    inc %itr
  }
  writeini -n aperçu.ini para normal 200,200,200
  writeini -n aperçu.ini para selected 0,100,200
  writeini -n aperçu.ini para b1 $µ(15)
  writeini -n aperçu.ini para b2 $µ(16)
  writeini -n aperçu.ini para b3 $µ(17)
  genere.toolbar aperçue pleine aperçu.ini
  .timeratool 1 20 window -c @&aperçue
  .remove aperçu.ini
}

on *:dialog:toolbar:sclick:26:{
  set %itr 1 
  set %save.file $r2(file)
  while ( %itr <= 5) { 
    writeini -n aperçu.ini texte n $+ %itr Selection:echo -a aperçu des selections 
    inc %itr
  }
  writeini -n aperçu.ini para normal 200,200,200
  writeini -n aperçu.ini para selected $µ(23) $+ , $+ $µ(24) $+ , $+ $µ(25)
  writeini -n aperçu.ini para b1 100
  writeini -n aperçu.ini para b2 100
  writeini -n aperçu.ini para b3 100
  genere.toolbar aperçue pleine aperçu.ini
  .timeratool 1 20 window -c @&aperçue
  .remove aperçu.ini
}

on *:dialog:toolbar:sclick:34:{ 
  if ( $window(@&aperçue) != $null ) { window -c @&aperçue | .timeratool off }
  set %itr 1 
  while ( %itr <= 5) { 
    writeini -n aperçu.ini texte n $+ %itr Texte Normal:echo -a aperçu du texte normal
    inc %itr
  }
  writeini -n aperçu.ini para normal $µ(31) $+ , $+ $µ(32) $+ , $+ $µ(33)
  writeini -n aperçu.ini para selected 0,100,200
  writeini -n aperçu.ini para b1 100
  writeini -n aperçu.ini para b2 100
  writeini -n aperçu.ini para b3 100
  genere.toolbar aperçue pleine aperçu.ini
  .timeratool 1 20 window -c @&aperçue
  .remove aperçu.ini
}

on *:dialog:toolbar:sclick:35:{ 
  set %itr 1 
  unset %ligne
  if ( $window(@&aperçue) != $null ) { window -c @&aperçue | .timeratool off }
  while ( %itr <= $did(6).lines) { 
    if ( $gettok($did(6,%itr).text,0,58) != 2 ) && ( $did(6,%itr).text != $null ) { set %ligne %ligne %itr }
    writeini -n aperçu.ini texte n $+ %itr $did(6,%itr).text 
    inc %itr
  }
  writeini -n aperçu.ini para normal $µ(31) $+ , $+ $µ(32) $+ , $+ $µ(33)
  writeini -n aperçu.ini para selected $µ(23) $+ , $+ $µ(24) $+ , $+ $µ(25)
  writeini -n aperçu.ini para b1 $µ(15)
  writeini -n aperçu.ini para b2 $µ(16)
  writeini -n aperçu.ini para b3 $µ(17)
  if ( %ligne != $null ) { echo -s [Erreur] a la ou aux ligne %ligne | .remove aperçu.ini | halt }
  genere.toolbar aperçue pleine aperçu.ini
  .timeratool 1 20 window -c @&aperçue
  .remove aperçu.ini
}

on 1:dialog:toolbar:edit:*: { 
  if ( $did = 6 ) || ( $did = 7 ) { goto fin } 
  if ( $window(@aperçu) = $null ) { window -hkp +b @aperçu 0 0 100 100  }
  if ( $did <= 17) { drawfill -r @aperçu $rgb($µ(15),$µ(16),$µ(17)) $rgb($µ(15),$µ(16),$µ(17)) 0 0 | did -a toolbar 38 Bouton  }
  elseif ( $did <= 25) && ( $did >= 23 ) { drawfill -r @aperçu $rgb($µ(23),$µ(24),$µ(25)) $rgb($µ(23),$µ(24),$µ(25)) 0 0 | did -a toolbar 38 Texte Sélectionnné }
  elseif ( $did <= 33) && ($did >= 31) { drawfill -r @aperçu $rgb($µ(31),$µ(32),$µ(33)) $rgb($µ(31),$µ(32),$µ(33)) 0 0 | did -a toolbar 38 Texte Normal }
  drawsave @aperçu @aperçu.bmp
  did -g toolbar 37 $mircdir $+ @aperçu.bmp
  :fin
}

dialog erreur.t { 
  title "Erreur Toolbar"
  size -1 -1 160 55
  text il manque '':'' a  la ligne %ligne ,1,20 10 150 20
  button "OK" ,2,20 30 100 20,flat,ok
}

on *:dialog:erreur.t:sclick:2:{ color.tool }

menu @&* { 
  mouse : {
    set %itr 1
    set %position 3
    while ( %itr <= $r2(get0)) { 
      if ( $inrect($mouse.x,$mouse.y,%position,2,$r2(type),20) = $true ) { 
        drawtext -r $active $rgb($g(selected,1),$g(selected,2),$g(selected,3)) $calc(%position +5) 2 $gettok($r1(%itr),1,58)
      }
      else { drawtext -r $active $rgb($g(normal,1),$g(normal,2),$g(normal,3)) $calc(%position +5) 2 $gettok($r1(%itr),1,58) }
      inc %position $calc($r2(type) +10)
      inc %itr
    } 
  }
  sclick : {
    set %itr 1
    set %position 3
    while ( %itr <= $r2(get0)) { 
      if ( $inrect($mouse.x,$mouse.y,%position,2,$r2(type),20) = $true ) { 
        $gettok($r1(%itr),2,58) 
        $csb($remove($active,@&),2,%position,$r2(type),20)
      }
      inc %position $calc($r2(type) +10)
      inc %itr
    } 
  }
}