insersion de lettres

Réponse acceptée !
Pour remplacer une phrase par des *, utilise :
$regsubex(Ta phrase,/\S/g,*)
Dès qu'une lettre est "demandé", utilise if ($regex(La phrase,/Lettre/g)) pour savoir si la lettre est dedans, et pour remplacer les lettres utilise $regsubex(La Phrase,/([^ ])/g,*) un petit exemple :

alias testr {
  var -s %p Ga is Ga lol
  echo -a texte a afficher : $regsubex(%p,/\S/g,*)
  echo -a On demande la lettre a
  echo -a la lettre a est présente $regex(%p,/a/g) fois
  Echo -a texte a afficher avec remplacement de la lettre %a : $regsubex(%p,/[^a ]/g,*)
}

tape /testr :)

Réponse acceptée !
Petite correction, pour remplacer les lettres, utilise $regsubex(La phrase,/[^Lettre ]/g,*)
(l'espace entre la lettre et le ] est important)

Réponse acceptée !
Si c'est un peudu que tu veux faire, tu peux mettre ce code sur un bot et lui taper !pendu #tonsalon "la phrase" en privé

alias pendu echo -a Nouveau pendu : !pendu <#salon> <phrase> en PV :: Ensuite pour jouer sur #salon : !pendu <lettre|mot|phrase>
on *:text:!pendu *:*:{
  tokenize 32 $strip($1-)
  if (!$2-) return
  if (!$chan) {
    if (!$3) return
    if ($left($2,1) != $chr(35)) return
    if ($hget(Pendu)) hfree Pendu
    hadd -m Pendu Salon $2
    hadd -m Pendu Mot $3-
    var %r $regsubex($hget(Pendu,Mot),/[a-z]/ig,_)
    hadd -m Pendu Masque %r
    msg $2 Pendu - Nouveau mot : $regsubex(%r,/(_+)/g,$+($str(_,$len(\t)),$chr(40),$len(\t),$chr(41))) $+($chr(40),Proposé par $nick,$chr(41))
  }
  elseif (($chan == $hget(Pendu,Salon)) && ($hget(Pendu,Mot))) {
    var %r = $hget(Pendu,Masque), %e = $2-, %p = $pos($hget(Pendu,Mot),%e,0)
    if (!%p) hinc -m Pendu Score
    while %p {
      var %s = $calc($pos($hget(Pendu,Mot),%e,%p) -1), %m = $+(/^,$left(%r,%s),$chr(40),$str(.,$len(%e)),$chr(41),/i), %r = $regsubex(%r,%m,$+($left(%r,%s),%e))
      dec %p
    }
    if ($pos($hget(Pendu,Mot),_,0) == $pos(%r,_,0)) {
      msg $chan Bravo, vous avez réussi ce pendu ! Il s'agit effectivement de : $hget(Pendu,Mot)
      hdel Pendu Mot
    }
    elseif (%r != $hget(Pendu,Masque)) {
      hadd -m Pendu Masque %r
      msg $chan Pendu : %r
    }
    else msg $chan Faux $nick !
    if ($hget(Pendu,Score) > 5) {
      msg $chan Perdu ! C'était $hget(Pendu,Mot)
      .timer -m 1 500 kick $chan $nick Perdu ! C'était $hget(Pendu,Mot)
      hfree Pendu
    }
  }
}

ça peut très certainement être simplifiable, je l'ai fait de ça il y a plusieurs années, mais j'ai la flemme de m'y remettre ... :(